TSAYTEST Procedure

@TSAYTEST performs an arranged regression test for threshold autoregression (though it can be used in more general situations). This is based upon the recursive estimation of a regression with data points added in order based upon a desired threshold series. From Tsay(1989). An alternative procedure for testing for the same type of break is @THRESHTEST.

@TSAYTEST(threshold=threshold series,other options) depvar start end

# list of regressors(in regression format).

Parameters

depvar	dependent variable
start, end	range for regression. By default, the maximum range permitted by all variables involved in the regression.

Options

THRESHOLD=series to use for threshold values

D=delay of the threshold series [0]

TITLE="title for output" ["Tsay Arranged Autoregression Test"]

[PRINT]/NOPRINT

GRAPH/[NOGRAPH]

If GRAPH, a SCATTER plot of the threshold series against the recursive residuals is created.

Variables Defined

%CDSTAT	the computed test statistic (REAL)
%SIGNIF	the marginal significance level (REAL)

Example

This does tests for threshold effects using different lags of the dependent variable, in both direct and reverse order (reverse order by doing - the series).

* Replication of Balke and Fomby(1997), "Threshold Cointegration,"

* International Economic Review, vol 38, no 3, 627-45.

cal(m) 1954:7

open data irates.xls

data(format=xls,org=columns) 1955:01 1990:12 fedfunds mdiscrt

set spread = fedfunds-mdiscrt

@dfunit(lags=12) fedfunds

@dfunit(lags=12) mdiscrt

@dfunit(lags=12) spread

* Pick lags

@arautolags(crit=hq) spread

* Tsay threshold tests with direct ordering

do d=1,4

@tsaytest(title="Threshold Test with Delay="+d,thresh=spread,d=d) spread

# constant spread{1 2}

end do d

* And with reversed ordering

set reverse = -spread

do d=1,4

@tsaytest(title="Threshold Test Reversed with Delay="+d,thresh=reverse,d=d) spread

# constant spread{1 2}

end do d

Sample Output

This is for the reversed order test in the example. It appears there may be a threshold break, with lag 1 as the threshold variable showing the greatest effect.

Threshold Test Reversed with Delay=1

F(3,424) 26.979 Signif 0.000

Threshold Test Reversed with Delay=2

F(3,424) 18.219 Signif 0.000

Threshold Test Reversed with Delay=3

F(3,423) 10.567 Signif 0.000

Threshold Test Reversed with Delay=4

F(3,422) 5.425 Signif 0.001