INSTRUMENTS Instruction

INSTRUMENT( options ) exogenous variables (in Regression Format)

Sets the instrument list to be used by subsequent instructions. See Instrumental variables for more information.

Wizards

The relevant regression and estimation wizards provide fields for including instruments, so you don't need to do a separate INSTRUMENTS instruction if you will be using a wizard to do the estimation.

Parameters

exogenous variables

this is the list of exogenous (or pre-determined) variables that will be used in future instructions that have an INSTRUMENTS option.

Options

DROP/[NODROP]

ADD/[NOADD]

With ADD and DROP, you can make small changes to the existing list of exogenous variables. ADD adds the new list to the existing one, while DROP removes any of the listed variables. ADD and DROP are useful when you estimate large models with many potential instruments. If each equation uses a different subset of the instruments, these options can simplify specification of the instrument sets.

PRINT/[NOPRINT]

Use PRINT to list the current set of instruments.

Variables Defined

%NINSTR

number of variables on the list (VECTOR)

Examples

instruments constant trend govtwage taxes govtexp $

capital{1} prod{1} profit{1}

linreg(inst) cons

# constant profit{0 1} wagebill

linreg(inst) invst

# constant profit{0 1} capital{1}

linreg(inst) privwage

# constant prod{0 1} trend

estimates the equations for Klein's Model I. The one set of instruments is used throughout the model and doesn't have to be repeated.

* Estimate the model with six lags in the information set

instruments constant consgrow{1 to 6} realret{1 to 6}

nlls(inst,frml=h,optimal) *

sets an information set for a non-linear GMM estimation.

panel(effects=time,dummies=tdummies) constant

@ablags p_n ablogn

instruments ablogn dw{0 1} dk{0 1 2} dys{0 1 2} tdummies

generates a set of time dummies using PANEL, generates a set of Arellano-Bond instruments, and sets the instrument set using those.

instruments constant

nlsystem(instruments) / mom2

nlsystem(instruments) / mom2 mom4

cdf(title="Test of Overidentifying Restrictions") chisqr %uzwzu 1

This estimates a model using moment restrictions. The only instrument is the CONSTANT, which means that the FRMLs MOM2 and MOM4 are specifying formulas which sum to zero (theoretically) over the sample.

Notes

The instruction NLSYSTEM has a special option MASK which allows a different set of instruments to be used for each equation in the system. You have to provide a RECTANGULAR array with dimensions “number of instruments” x “number of formulas” which has 1.0 in a cell in the column j if and only if you want instrument i to be used for formula j. For instance:

instruments constant csz{1 to 4} pcs{1 to 4} aaz{1 to 4}

dec rect mask(13,2)

compute %do(i,1,13,mask(i,1)=(i<=9))

compute %do(i,1,13,mask(i,2)=(i<=5.or.i>=10))

nlsystem(mask=mask,instruments) / frm1 frm2

would use CONSTANT, lags of CSZ and lags of PCS for the first formula and CONSTANT, lags of CSZ and lags of AAZ in the second.

You need to be careful in using lags as instruments. For instance, in the example of the large simultaneous equations model above, lags 1 to 4 of Y are used as instruments. Since Y{4} isn’t available until T=5 (at a minimum), the estimation range can start no earlier than period 5. This can be a major problem in a panel data set, as you lose data points in each cross section. An alternative to using lag notation is to create a separate series for each lag, but with zero values where the lagged data is unavailable. For panel data, use the %PERIOD function to get the time period within an individual’s data. For instance, rather than Y{1 to 4}, you could do the following:

set y1 = %if(%period(t)<=1,0.0,y{1})

set y2 = %if(%period(t)<=2,0.0,y{2})

set y3 = %if(%period(t)<=3,0.0,y{3})

set y4 = %if(%period(t)<=4,0.0,y{4})

and then use Y1 Y2 Y3 Y4 on the instrument list.