The RATS Software Forum

Code: Select all

*
* Joint estimation of pricing kernel with three Fama-French factors
*
open data gmm1996.xls
calendar(m) 1996:1
data(format=xls,org=columns) 1996:01 2013:06 smb lmh mkt_tvw_a highfbig_excess highfmedium_excess highfsmall_excess $
 LowFBig_excess LowFMedium_excess LowFSmall_excess MedFBig_excess MedFMedium_excess MedFSmall_excess $
 Trd_year Trd_month
*
* This sets up the time series regressions to be estimated by non-linear GMM. This
* matches exactly with OLS equation by equation, so is overkill, but it's a useful
* first step.
*
compute np=9
*
dec vect[int] portfolios(np)
compute portfolios=||HighFBig_excess,HighFMedium_excess,HighFSmall_excess,LowFBig_excess,$
  LowFMedium_excess,LowFSmall_excess,MedFBig_excess,MedFMedium_excess,MedFSmall_excess||
*
compute nf=3
dec vect[int] factors(nf)
compute factors=||Mkt_tvw_a,Smb,Lmh||
*
dec vect[frml] tserrors(np)
dec rect[frml] tsconditions(nf+1,np)
dec rect       tsparms(nf+1,np)
*
do i=1,np
   frml tserrors(i) = portfolios(&i){0}-tsparms(1,&i)-tsparms(2,&i)*factors(1){0}-$
           tsparms(3,&i)*factors(2){0}-tsparms(4,&i)*factors(3){0}
   frml tsconditions(1,i) = tserrors(&i){0}
   do j=1,nf
      frml tsconditions(j+1,i) = tserrors(&i){0}*factors(&j){0}
   end do j
end do i
*
compute tsparms=%zeros(nf+1,np)
nonlin tsparms
instruments constant
*
nlsystem(inst) / tsconditions
*
* Get guess values for the pricing function by averaging across securities.
*
dec vector lambda
compute lambda=%xsubvec(%sumr(tsparms),2,nf+1)
disp "OLS estimates" lambda
*
* Create the cross-section conditions
*
dec vect[frml] csconditions(np)
do i=1,np
   frml csconditions(i) = portfolios(&i){0}-lambda(1)*tsparms(2,&i)-$
      lambda(2)*tsparms(3,&i)-lambda(3)*tsparms(4,&i)
end do i
*
* Estimate the joint system. This is using a 12 lag Bartlett window to handle the
* (likely) autocorrelation in the moment conditions.
*
nonlin tsparms lambda
nlsystem(inst,lags=12,lwindow=newey,zudep,update=once,swout=sw) / tsconditions csconditions