Structural Model

[Shenelle]

I am trying to solve the following equations for a multiplier.
I know that a structural model was used but I am not sure what to use or how to obtain a range of values for the coefficients.
Can anyone please see the attached file and assist,? This is very improtant for my thesis.

[TomDoan]

Are there any dynamics in that model? There don't appear to be.

I'm assuming that you're interested in some type of comparison with different settings for the parameters. This is probably the most flexible way to set this up to do experiments.

Code: Select all

dec real alpha cc
dec real beta d e
dec real gamma im f
dec real phi xx gg
*
dec series c y in m x 
dec series r reer g p
*
frml(identity) f1 = c  - (alpha+cc*y)
frml(identity) f2 = in - (beta+d*y+e*r)
frml(identity) f3 = m  - (gamma+im*y+f*reer)
frml(identity) f4 = x  - (phi+xx*p+gg*reer)
frml(identity) f5 = y  - (c+in+g+x-m)
frml           s1 = g
frml           s2 = r
frml           s3 = reer
frml           s4 = p
*
group simulmod f1 f2 f3 f4 f5 s1 s2 s3 s4
*
compute alpha=5.0,cc=.9
compute beta=2.0,d=.05,e=-2.0
compute gamma=1.0,im=.03,f=0.0
compute phi=4.0,xx=-.2,gg=0.0
*
dsge(model=simulmod,a=adsge,f=fdsge,z=zdsge) y c in m x g r reer p
*
* The impact multiplier for g on y is in fdsge(1,1)
*
set testc  1 200 = .80+.001*(t-1)
set impact 1 200 = 0.0
do i=1,200
   compute cc=testc(i)
   dsge(model=simulmod,a=adsge,f=fdsge,z=zdsge) y c in m x g r reer p
   compute impact(i)=fdsge(1,1)
end do i
scatter(style=lines,footer="Showing instability at c=.98")
# testc impact 1 200
scatter(style=lines)
# testc impact 1 150

[Shenelle]

Thank you. I'll try and see if it works!